ESP32 Stepper Motor Controller

//  MakerStore.com.au

#include <ezButton.h>
#include <SPI.h>
#include <TFT_eSPI.h>
#include "logo.h"
#include <AccelStepper.h>

TFT_eSPI tft = TFT_eSPI(); // Invoke custom library for the TFT Screen

ezButton limitSwitch_1(18); // create ezButton object that attach to pin 18
ezButton limitSwitch_2(21); // create ezButton object that attach to pin 21
ezButton redButton(13);     // create ezButton object that attach to pin 13
ezButton blueButton(32);    // create ezButton object that attach to pin 32
ezButton whiteButton(33);   // create ezButton object that attach to pin 33

const int DIR = 2;  // Stepper DIR Pin 2
const int STEP = 0; // Stepper STEP Pin 0

AccelStepper stepper(1, STEP, DIR);  // Set the Stepper Motor

// Define program variables
int maxSpeed = 1000;
int speed = 500;
int direction = 1;
int action = 0;

void setup() {

  limitSwitch_1.setDebounceTime(50); // set debounce time to 50 milliseconds
  limitSwitch_2.setDebounceTime(50); // set debounce time to 50 milliseconds
  redButton.setDebounceTime(50);     // set debounce time to 50 milliseconds
  blueButton.setDebounceTime(50);    // set debounce time to 50 milliseconds
  whiteButton.setDebounceTime(50);   // set debounce time to 50 milliseconds

  // Initalise the TFT Screen
  tft.init();
  tft.fillScreen(TFT_BLACK);
  tft.drawXBitmap(0, 0, logo, 128, 20, TFT_WHITE);
  tft.setCursor(0, 30, 2);
  tft.print("SPEED = ");
  tft.println(speed);
  tft.setTextColor(TFT_WHITE, TFT_BLACK);

  stepper.setMaxSpeed(maxSpeed);   // set the maximum speed
  stepper.setAcceleration(10); // set acceleration
  stepper.setSpeed(speed);         // set initial speed
  stepper.setCurrentPosition(0);   // set position to 0

}

void loop() {

  // MUST call all the button loop() functions first
  limitSwitch_1.loop();
  limitSwitch_2.loop();
  redButton.loop();
  blueButton.loop();
  whiteButton.loop();

  stepper.setSpeed(speed);         // set Stepper speed

  // Write the Stepper Position to the screen
  tft.setCursor(0, 50, 2);
  tft.print("POSITION = ");
  tft.setCursor(70, 50, 2);
  tft.print("       ");
  tft.setCursor(70, 50, 2);
  tft.println(stepper.currentPosition());

  // All the button actions
  // when a button is pressed it calls the case condition below based on the action number
  // action = 0 change speed
  // action = 1 change direction
  // action = 2 stop
  // action = 3 nothing (reset action var)
  if (limitSwitch_1.isReleased()) {
    stepper.setCurrentPosition(0);
    action = 1;
  }
  if (limitSwitch_2.isReleased()) {
    action = 1;
  }
  if (blueButton.isPressed()) {
    action = 0;
    tft.setCursor(0, 105, 2);
    tft.println("BLUE BUTTON   ");
  }
  if (whiteButton.isPressed()) {
    action = 1;
    tft.setCursor(0, 105, 2);
    tft.println("WHITE BUTTON");
  }
  if (redButton.isPressed()) {
    action = 2;
    tft.setCursor(0, 105, 2);
    tft.println("RED BUTTON    ");
  }

  // Conditions called but the action variable sest by pressing buttons
  switch (action) {
    case 0:  // CHANGE SPEED
      if (speed >= 0) direction = 1 ;
      else direction = -1;
      speed = abs(speed);
      if (speed != maxSpeed) {
        speed += 100;
      } else {
        speed = 100;
      }
      speed *= direction;
      tft.setCursor(0, 30, 2);
      tft.println("                   ");
      tft.setCursor(0, 30, 2);
      tft.print("SPEED = ");
      tft.println(abs(speed));
      action = 3;
      break;

    case 1:  //CHANGE DIRECTION
      speed *= -1;
      tft.setCursor(0, 70, 2);
      if (speed > 0) {
        tft.println("=> RIGHT");
      } else {
        tft.println("<= LEFT     ");
      }
      action = 3;
      break;

    case 2:  // STOP
      stepper.stop();
      tft.setCursor(0, 30, 2);
      tft.print("SPEED = ");
      tft.println("0     ");
      break;

  }

  // Run thhe Stpper as long as the action case is not 2
  if (action != 2) {
    stepper.runSpeed();
  }
}